bat小工具之自动Mysql数据库备份

这里收藏整理了一个使用Windows Bat命令实现本地mysql数据库自动导出的小工具代码，配合计划任务调用这个bat定期执行，便可以实现数据库的定时自动备份功能了！
Bat代码如下：

@echo off
 
rem 脚本使用配置开始=======================start
::设置数据库所在ip
set ip=数据库所在ip
::设置数据库端口
set port=数据库端口
::设置数据库连接用户（为了保证导出函数，视图，存储过程，触发器请给用户设置权限）
set user=账号
::设置数据库连接用户密码（密码中的%需要两个%%转义）
set password="密码"
::设置备份文件存储位置
set dataFolder=D:/mysql_backup
::设置压缩软件WinRAR的安装目录
set winrarPath="C:\Program Files\WinRAR"
::设置MySQL的安装目录的安装目录
set mysqlPath="D:\Program Files\MySQL\MySQL Server 5.6\bin"
::设置备份日期
set curdate=%date:~0,4%%date:~5,2%%date:~8,2%
rem 脚本使用配置结束=======================end
 
echo 开始备份=======
 
%mysqlPath%\mysqldump.exe -R -u%user% -p%password% -h%ip% -P%port% 需要备份的数据库名 > %dataFolder%/backup_%curdate%.sql
 
rem 压缩备份文件
::若压缩文件存在，先删除
if exist "%dataFolder%/nonauto_backup_%curdate%.rar" (
    del %dataFolder%/nonauto_backup_%curdate%.rar
)
::使用WinRAR压缩文件并删除源文件
echo 开始压缩=======
%winrarPath%\Rar.exe a -k -r -s -m5 -ep1 -df %dataFolder%/nonauto_backup_%curdate%.rar %dataFolder%/backup_%curdate%.sql
 
echo 备份结束

老规矩，复制保存为bat文件便可点击执行了。代码里使用了mysqldump工具不了解的可以看这里，另外里面的一些参数地址根据自己的需求调整。